HOME > 電算 > Emacs メモ

Emacs Lisp

Emacs キーバインディングの変更

変更内容による難度（？）の違い

何（どういうコマンド）をどこ（どのキーシーケンス）に割り付けるかで、
やり方が異り、必要とされる技にも違いがある。

(a) 既存のコマンドを、
「Ctrl-c を押してから一文字を押す」というユーザ予約キーシーケンスに
引数を与えないで割り付ける。→ 簡単（以下を読むまでもなし）
例 (global-set-key "\C-ca" 'fill-region)

(b) 既成のコマンドに引数を与えて割り付ける → 説明が必要（ラムダ式など）

例 (global-set-key "\C-ca" 
  (lambda () (interactive) (backward-delete-char 2)))

(c) 自作のコマンドを作成して割り付ける → 説明が必要（コマンドとは何かなど）

例 
(defun my-command ()
  (interactive)
  (insert "a"))
(global-set-key "\C-ca" 'my-command)

(d) 「Ctrl-c を押してから一文字押す」というユーザ予約キーシーケンス以外の
キーシーケンスに割り付ける→ 説明が必要（モード・マップなど）

例
(add-hook 'text-mode-hook
             (lambda ()
	       (local-set-key "\t" 'self-insert-command)))

Emacs のキーバインディング設定を完全に行おうとすると、なかなかやっかいだ。いちど腰を据えて取り組んでみむ。

コマンドとは何か

(lambda (a b) (+ a b))
ラムダ式。無名関数の一つの形である。

(fset 'aplusb (lambda (a b) (+ a b)))
シンボル aplusb の関数セルにラムダ式を入れる。
ラムダ式がシンボル aplusb の関数定義になっている、とも言う。
これは

(defun aplusb (a b)
   (+ a b))
とやっても可能。

(funcall (lambda (a b) (+ a b)) 1 2)
と
(funcall 'aplusb 1 2)
は同じにはたらく。

((lambda (a b) (+ a b)) 1 2)
=> 3
リストを評価すると、第一要素が関数ならそれが実行されるから。

(aplusb 1 2)
=> 3
これは前の式と同じ結果をもたらす。なぜなら、リストを評価したとき、
第一要素がシンボルで、その関数セルに内容があればそれが実行されるから。

(symbol-function 'aplusb)
で、シンボルに与えられている関数定義を得ることができる。もっとも、

((symbol-function 'aplusb) 1 2)
とやってもエラー。これは、リストを評価のとき先頭要素は評価されないから。
ところで、

(setq aplusb (lambda (a b) (- b a)))
というように、シンボル aplusb の値セルに別のラムダ式を入れてやっても、

(aplusb 1 2)
=> 3
の結果は従前のまま。
リスト評価は、第一要素の関数セルの内容を実行するので、
値セルに入れておいたほうのラムダ式は用いられないから。

(funcall 'aplusb 1 2)
=> 3
この場合も同じ。

(funcall aplusb 1 2)
=> 1
これは、aplusb がいったん評価されて、値セルに入れたほうのラムダ式となるから。

(lambda () (insert "a"))
バッファに文字 a を挿入するラムダ式。

(functionp (lambda ()(insert "a")))
=> t
ラムダ式は関数。

(commandp (lambda () (insert "a")))
=> nil
しかしコマンドではない。

(commandp (lambda () (interactive) (insert "a")))
=> (interactive)
スペシャルフォーム（式の一種） interactive を関数の中に含めることで
その関数がコマンド（対話的に呼び出せる関数）であることを宣言できる。
　　※どうして戻り値が t でないのかわからぬが、とにかく nil ではない
　　　(commandp (byte-compile (lambda () (interactive) 1)))
　　　=> t
　　　みたいにバイトコンパイルしておくと t が返されるけどね。

(defun inserta ()
  (insert "a"))
関数セルにラムダ式が入っているシンボルも同様で、

(commandp 'inserta)
=> nil
それだけではコマンドとは言えない。

(defun inserta ()
  (interactive)
  (insert "a"))
コマンドであることを宣言しておけば、

(commandp 'inserta)
=> (Interactive)
そのシンボルはコマンドとみなされる。

キーマップをいかに書き換えるか

(global-set-key "\C-cz" (insert "a"))
よくあるキーバインディングの誤り。
リストの第三要素は任意の式でいいわけではない。

(global-set-key "\C-cz" (lambda () (insert "a")))
第三要素をラムダ式にしても、まだ使用時にエラーが出る。
ただの関数では駄目。

(global-set-key "\C-cz" (lambda () (interactive )(insert "a")))
コマンドだと宣言してある関数ならうまくいく。

(global-set-key "\C-cz" 'inserta)
関数そのもののかわりに、
関数セルにコマンドを入れてあるシンボルを使うこともできる。

(lookup-key global-map "\t")
=> indent-for-tab-command
たいがい、グローバルキーマップではタブに
indent-for-tab-command が割り付けられている。しかし、

(lookup-key lisp-mode-map "\t")
=> lisp-indent-line
ローカルキーマップのひとつ Lisp モードマップは
タブに lisp-indent-line が割りつけられていて、

(lookup-key c-mode-map "\t")
=> c-indent-line
またべつのローカルモードマップのひとつ C モードマップでは、
タブに c-indent-line が割り付けられている。それぞれの
メージャモードにおいてはグローバルマップより優先される。
さらに、

(minor-mode-key-binding "\t")
=> ((skk-j-mode . skk-insert))
活性化しているマイナーモードマップに該当するマッピングがあると、
　　※上の例では、現在、タブキーは skk-j-mode というマイナーモードマップで
　　　skk-insert が割り付けられている。

(key-binding "\t")
=> skk-insert
キー探索時にはマイナーモードマップのマッピングが最優先される。
globa-set-key でタブにお好みのコマンドをバインドしても、
効果がない場合、この種の優先順位が問題であることが少なくない。
マイナーモードマップに上書きされるのは覚悟しておくとして、
ローカルモードマップを書き換える方法を考えてみむ。

(local-set-key "\t" (lambda () (interactive )(insert "a")))
を現在のバッファ内で評価してやればローカルキーマップを書き換えられるが、
これを .emacs に書いておいても、各モードに入る前に評価されてしまうから
意味がない。

(define-key text-mode-map "\t" (lambda () (interactive) (insert "a")))
と .emacs にのように書いて、ローカルキーマップを直接上書きすれば
よさそうに思える。しかし、これはうまくいかない場合がある。
Lisp モードやテキストモードでは可能でも nroff モードでは駄目だったりとか。
Lisp モードマップやテキストモードマップは、.emacs を読み込む前に
作成されているので .emacs で変更可能だが、nroff モードマップは
.emacs 読み込み後 nroff モードに入ったときにはじめて作成されるからである。
そこでフックを使う。フックの例。たとえば、

(add-hook 'text-mode-hook 
	  (lambda () 
	    (insert "a")))
をまえもって評価しておくと、テキストモードに入った直後、
バッファに a という文字が挿入される。なお、ラムダ式は自己評価型（評価すると
自分自身を返すオブジェクト）なので add-hook 式の第三要素にしたときに、
クオートしなくても大丈夫である。

　　※(defun inserta () (insert "a"))
　　　(add-hook 'text-mode-hook 'inserta)
　　　関数セルに関数を入れたシンボルを add-hook リストの第2要素にするも可。
　　　これはもちろんクオートしておかないと駄目。クオートしていないシンボルを
      評価すると、値セルの内容が返されるから。

(add-hook 'text-mode-hook
	  (lambda ()
	    (local-set-key "\t" 'self-insert-command)))
タブキーで、タブを一つだけ入れるようにする。

(add-hook 'text-mode-hook
	  (lambda ()
	    (local-set-key "\t" (lambda ()
			          (interactive)
			          (insert "[TAB]")))))
タブキーで、[TAB] という文字列を挿入するようにする。
Emacs Lisp のマニュアルには、ふつうは新たに定義されたフック関数は
最後に実行される（と予測できる）とあるが、
私の Emacs は、新たなそれを最初に実行するようだ。

タブ

タブの動作

Emacs でタブキーを押すと、どのモードにいるかによってこれは違うが、たいがいは単純にタブ文字が挿入されるわけではない。たとえば、いじくる前の私の環境のテキストモードではタブキーにバインドされている関数は indent-relative である。これは、直前の行のインデンションに合わせ、それが無理なら tab-to-tabstop を使う。

tab-to-tabstop というのは、タブ文字・スペースを使って、文字の頭をそろえるものである。この時に tab-stop-list という変数が参照される。これはリストで、たとえば (8 16 24 32 40 48 56 64 72 80 88 96 104 112 120) というような形をしている。このリストは、edit-tab-stops という対話的な関数で設定することができる。重要なことは、このリストに表われる数字は等差数列になっていなくてもいいということ、つまりタブストップが等間隔でなくてもよいということである。

tab-to-tabstop は、タブ文字だけによって、インデンションを行うわけではない。タブ文字によるインデンションは、 tab-width という変数にしたがうが、これは、スカラーだから、等間隔のインデンションしか実現できない。tab-to-tabstop は、tab-stop-list で定めた位置までジャンプするために、まずタブを使ってみて、たりない分はスペースで埋めるのである。Emacs のインデンションはこのように二重の仕組みで実現されている。

タブ文字だけでなくスペースも動員するというのがちょっとやっかいである。たとえば頻繁に修正しながら表を書いていくような場合、タブ文字だけなら1 ストロークで消せるが、スペースの連続が挿入されると、数回以上バックスペースキーを押さなくてはならない。しかも、画面上はタブで空いた空間なのか、スペースで空いた空間なのか区別がつかないので、必要以上に消去することが稀ではない。また、なにより、tab-width を変更すると、表の形がくずれてしまう。

（indent-tabs-mode に nil を設定すると、tab-to-tabstop でスペースだけが使われるようになるし、untabify はタブをスペースに変換する。しかし、タブの便利さの一部は失われるように思う。）

原始的なタブ動作の実現

これに対する原始的な対処は、タブキーを、ちょうど一個だけのタブ文字を入力するようにすることだ。つまり、C-q [TAB] と同じことができればいい。ただし、グローバルなキーバインディングは、各モードに入ったときに上書きされてしまうから、設定ファイルを使って変更をするなら、モードを指定してやる必要がある。たとえば、テキストモードなら、

(add-hook 'text-mode-hook
             (lambda ()
	       (local-set-key "\t" 'self-insert-command)))

と、書いておけばよい。

原始的なタブ幅の設定

タブの幅は tab-width で決められるから、最も原始的には、

(set 'tab-width 2)

などという式を当該バッファで評価してやればよい。tab-width は、バッファにローカルな変数である。つまり、このように設定をしても他のバッファには影響がない。グローバル値は (default-value 'tab-width) を評価すると知ることができる。バッファローカルな値は、たんに tab-width を評価すればわかる。グローバル値を設定するには、(setq-default tab-width 2) などとやればよい。

map 関数

map 関数じたいは難しくはないのだが……。

(defun my-insert (x)
  (insert x))
(mapcar 'my-insert '("a" "b" "c"))

はバッファに abc を挿入する。

(defun my-insert (x)
  (insert x))
(setq y "a")
(mapcar 'my-insert '(y "b" "c"))

はエラーになる。

(defun my-insert (x)
  (insert (eval x)))
(setq y "a")
(mapcar 'my-insert '(y "b" "c"))

なら、ＯＫ。（"b" や "c" は eval しても元のままであることに注意）

my-insert 関数のほうをいじりたくなければ、

(defun my-insert (x)
  (insert x))
(setq y "a")
(mapcar '(lambda (z) (my-insert (eval z))) '(y "b" "c"))

としておけばいい。

ようするに (insert "a") は、"a" を insert しているのではなく、(eval "a") を insert してる。map 関数ではこの違いを意識しないといけない。

縦書きポストスクリプト・ドライバ

Emacs でテキストファイルを作成して、それを LaTeX かなにかで印刷するというのが、標準的なやり方に違いない。しかし、その場しのぎの簡易な印刷をするのに、いちいち dvi ファイルを生成してやるのは面倒である。

そう考える人が多いのは当然で、その結果簡単な印刷ソフトはいくらもある。しかし、私の知る限り、これらはみな横書きである。Emacs から安直・直接に縦書きプリントがでぬものかと考えた。

そこで、Emacs Lisp で縦書きの Postscript ファイルを生成してみることにした。自分用に作ったものだから、場当たり的で汚ないコーディング（その上たぶんバグいっぱい）だが、問題提起のつもりで晒しておくぜ。

ともかく、tatepri-08.el がそれである。

対話的に使用する関数は、以下の三つだけである。

tatepri は、現在訪れているバッファの内容を縦書きのポストスクリプトファイルにして、lpr に出力。
tatepri-edit-ps は、新規バッファに出力。
tatepri-gv は、gv に出力

（これは、「Vine Linux + ポストスクリプトプリンタ」時代に書いたのだが、最近「Ubuntu + 非ポストスクリプトプリンタ」で試したら、もう少し手間をかけないといけなかった。まず、ghostscript が日本語を表示できるようにフォントを設定されている必要がある。フォントは Ryumin-Light になっているので、hint ファイルに Alias を書いておく必要もありそう。また、ポストスクリプト・ファイルを直接 lpr コマンドで cups に送り、API フォントで出力しようとしたら、なぜかメトリックが滅茶滅茶になった。ps2ps で翻訳してからやったらうまくいった。）

用紙サイズ、版面位置（端の余白）、フォントサイズ、行送りの設定は、自分で tatepri.el 本体の最初のほうを書き換える :-)

こうした印刷設定をファイルごとに覚えておくためには、「ファイル内のローカル変数」というのを用いるのが最良である。
（参考 http://www.gnu.org/software/emacs/manual/emacs.html#File%20Variables
日本語 http://flex.ee.uec.ac.jp/texi/emacs-jp/emacs-jp_214.html#SEC236）

以下のようなものを、テキストファイルの末尾に追加しておくと、そのファイルを読み込んだときに、変数が設定される（もしそれが編集中のファイルならば、いったん保存してから revert-buffer をかける必要あり）。これは、tatepri.el の機能ではなく、Emacs が持っている機能を利用しているだけである。

;;; Local Variables: ***
;;; tatepri-paper-position: landscape ***
;;; tatepri-paper-rotation: nil ***
;;; tatepri-right-margin: 113.38582677165354 ***
;;; tatepri-upper-margin: 113.38582677165354 ***
;;; tatepri-font-size: 10.0 ***
;;; tatepri-okuri: 18.0 ***
;;; tatepri-chars-per-line: 40 ***
;;; tatepri-lines-per-page: 35 ***
;;; tatepri-show-handura: nil ***
;;; tatepri-tate-jp-font: "/Ryumin-Light-V" ***
;;; tatepri-yoko-jp-font: "/Ryumin-Light-H" ***
;;; tatepri-tate-ascii-font: "/Courier" ***
;;; tatepri-yoko-ascii-font: "/Courier" ***
;;; comment-start: ";;; "  ***
;;; comment-end:"***" ***
;;; End: ***

なお、いまのところこの方法により紙のサイズを設定することはできない。また、単位はポイントに換算して書いておかなければならない。ポイントに換算する関数は tatepri.el に入っているので、たとえば、(pt (cm 4)) を C-x C-e で評価してやったりすると cm をポイントに換算できる。

バッチ処理でポストスクリプトファイルを作成するには emacs -batch -load /somewhere/tatepri.el -file source.txt -funcall tatepri-edit-ps -f save-buffer などとする。保存ファイル名を尋ねてくるので、これを入力してやる。「青空文庫」などにあるようなフリーのテキストをこの方法でポストスクリプトファイルにして gv で読んだりしている。